iss: take version from iscc command line or __version__.py

Requires InnoSetup Preprocessor to be installed.

contrib/win32/mercurial.iss

@@ -1,103 +1,119 b''
 ; Script generated by the Inno Setup Script Wizard.
 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
+
+#ifndef VERSION
+#define FileHandle
+#define FileLine
+#define VERSION = "unknown"
+#if FileHandle = FileOpen(SourcePath + "\..\..\mercurial\__version__.py")
+  #expr FileLine = FileRead(FileHandle)
+  #expr FileLine = FileRead(FileHandle)
+  #define VERSION = Copy(FileLine, Pos('"', FileLine)+1, Len(FileLine)-Pos('"', FileLine)-1)
+#endif
+#if FileHandle
+  #expr FileClose(FileHandle)
+#endif
+#pragma message "Detected Version: " + VERSION
+#endif
+
 [Setup]
 AppCopyright=Copyright 2005-2009 Matt Mackall and others
 AppName=Mercurial
-AppVerName=Mercurial snapshot
+AppVerName=Mercurial {#VERSION}
 InfoAfterFile=contrib/win32/postinstall.txt
 LicenseFile=COPYING
 ShowLanguageDialog=yes
 AppPublisher=Matt Mackall and others
 AppPublisherURL=http://mercurial.selenic.com/
 AppSupportURL=http://mercurial.selenic.com/
 AppUpdatesURL=http://mercurial.selenic.com/
 AppID={{4B95A5F1-EF59-4B08-BED8-C891C46121B3}
 AppContact=[e-mail]
-OutputBaseFilename=Mercurial-snapshot
+OutputBaseFilename=Mercurial-{#VERSION}
 DefaultDirName={pf}\Mercurial
 SourceDir=..\..
-VersionInfoDescription=Mercurial distributed SCM
+VersionInfoDescription=Mercurial distributed SCM (version {#VERSION})
 VersionInfoCopyright=Copyright 2005-2009 Matt Mackall and others
 VersionInfoCompany=Matt Mackall and others
 InternalCompressLevel=max
 SolidCompression=true
 SetupIconFile=contrib\win32\mercurial.ico
 AllowNoIcons=true
 DefaultGroupName=Mercurial
 PrivilegesRequired=none
 
 [Files]
 Source: contrib\mercurial.el; DestDir: {app}/Contrib
 Source: contrib\vim\*.*; DestDir: {app}/Contrib/Vim
 Source: contrib\zsh_completion; DestDir: {app}/Contrib
 Source: contrib\hgk; DestDir: {app}/Contrib; DestName: hgk.tcl
 Source: contrib\win32\ReadMe.html; DestDir: {app}; Flags: isreadme
 Source: contrib\mergetools.hgrc; DestDir: {tmp};
 Source: contrib\win32\mercurial.ini; DestDir: {app}; DestName: Mercurial.ini; Check: CheckFile; AfterInstall: ConcatenateFiles;
 Source: contrib\win32\postinstall.txt; DestDir: {app}; DestName: ReleaseNotes.txt
 Source: dist\hg.exe; DestDir: {app}; AfterInstall: Touch('{app}\hg.exe.local')
 Source: dist\python*.dll; Destdir: {app}; Flags: skipifsourcedoesntexist
 Source: dist\library.zip; DestDir: {app}
 Source: dist\mfc*.dll; DestDir: {app}
 Source: dist\msvc*.dll; DestDir: {app}
 Source: dist\Microsoft.VC*.CRT.manifest; DestDir: {app}; Flags: skipifsourcedoesntexist
 Source: dist\Microsoft.VC*.MFC.manifest; DestDir: {app}; Flags: skipifsourcedoesntexist
 Source: dist\w9xpopen.exe; DestDir: {app}
 Source: dist\add_path.exe; DestDir: {app}
 Source: doc\*.html; DestDir: {app}\Docs
 Source: locale\*.*; DestDir: {app}\locale; Flags: recursesubdirs createallsubdirs
 Source: templates\*.*; DestDir: {app}\Templates; Flags: recursesubdirs createallsubdirs
 Source: CONTRIBUTORS; DestDir: {app}; DestName: Contributors.txt
 Source: COPYING; DestDir: {app}; DestName: Copying.txt
 
 [INI]
 Filename: {app}\Mercurial.url; Section: InternetShortcut; Key: URL; String: http://mercurial.selenic.com/
 
 [UninstallDelete]
 Type: files; Name: {app}\Mercurial.url
 
 [Icons]
 Name: {group}\Uninstall Mercurial; Filename: {uninstallexe}
 Name: {group}\Mercurial Command Reference; Filename: {app}\Docs\hg.1.html
 Name: {group}\Mercurial Configuration Files; Filename: {app}\Docs\hgrc.5.html
 Name: {group}\Mercurial Ignore Files; Filename: {app}\Docs\hgignore.5.html
 Name: {group}\Mercurial Web Site; Filename: {app}\Mercurial.url
 
 [Run]
 Filename: "{app}\add_path.exe"; Parameters: "{app}"; Flags: postinstall; Description: "Add the installation path to the search path"
 
 [UninstallRun]
 Filename: "{app}\add_path.exe"; Parameters: "/del {app}"
 
 [UninstallDelete]
 Type: files; Name: "{app}\hg.exe.local"
 [Code]
 var
   WriteFile: Boolean;
   CheckDone: Boolean;
 
 function CheckFile(): Boolean;
 begin
   if not CheckDone then begin
     WriteFile := True;
     if FileExists(ExpandConstant(CurrentFileName)) then begin
         WriteFile := MsgBox('' + ExpandConstant(CurrentFileName) + '' #13#13 'The file already exists.' #13#13 'Would you like Setup to overwrite it?', mbConfirmation, MB_YESNO) = idYes;
     end;
     CheckDone := True;
   end;
   Result := WriteFile;
 end;
 
 procedure ConcatenateFiles();
 var
   MergeConfigs: TArrayOfString;
 begin
   if LoadStringsFromFile(ExpandConstant('{tmp}\mergetools.hgrc'),MergeConfigs) then begin
     SaveStringsToFile(ExpandConstant(CurrentFileName),MergeConfigs,True);
   end;
 end;
 
 procedure Touch(fn: String);
 begin
   SaveStringToFile(ExpandConstant(fn), '', False);
 end;

contrib/win32/win32-build.txt

@@ -1,109 +1,115 b''
 The standalone Windows installer for Mercurial is built in a somewhat
 jury-rigged fashion.
 
 It has the following prerequisites, at least as I build it:
 
   Python for Windows
       http://www.python.org/ftp/python/2.4.3/python-2.4.3.msi
 
   MinGW
       http://www.mingw.org/
 
   Python for Windows Extensions
       http://sourceforge.net/projects/pywin32/
 
   mfc71.dll (just download, don't install; not needed for Python 2.6)
       http://starship.python.net/crew/mhammond/win32/
 
   Visual C++ 2008 redistributable package (needed for Python 2.6)
       http://www.microsoft.com/downloads/details.aspx?familyid=9b2da534-3e03-4391-8a4d-074b9f2bc1bf&displaylang=en
       
   The py2exe distutils extension
       http://sourceforge.net/projects/py2exe/
 
   GnuWin32 gettext utility
       http://gnuwin32.sourceforge.net/packages/gettext.htm
 
   Inno Setup
-      http://www.jrsoftware.org/isinfo.php
+      http://www.jrsoftware.org/isdl.php#qsp
+
+      Get and install ispack-5.3.4.exe which includes Inno Setup Processor,
+      which is necessary to package Mercurial.
 
   ISTool - optional
       http://www.istool.org/default.aspx/
 
   add_path (you need only add_path.exe in the zip file)
       http://www.barisione.org/apps.html#add_path
 
   Asciidoc - optional
       http://www.methods.co.nz/asciidoc/
 
 And, of course, Mercurial itself.
 
 Once you have all this installed and built, clone a copy of the
 Mercurial repository you want to package, and name the repo
 C:\hg\hg-release.
 
 In a shell, build a standalone copy of the hg.exe program:
 
   python setup.py build -c mingw32
   python setup.py py2exe -b 1
 
 Note: the previously suggested combined command of "python setup.py build -c
 mingw32 py2exe -b 1" doesn't work correctly anymore as it doesn't include the
 extensions in the mercurial subdirectory.
 
 If you want to create a file named setup.cfg with the contents:
 
 [build]
 compiler=mingw32
 
 you can skip the first build step.
 
 Copy add_path.exe into the dist directory that just got created.
 
 If you are using Python up to version 2.5.4, copy mfc71.dll into the dist
 directory that just got created.
 
 If you are using Python 2.6 or later, after installing the Visual C++ 2008
 redistributable package copy into the dist directory that just got created the
 following files:
   - from the directory starting with
     Windows/WinSxS/x86_Microsoft.VC90.CRT_1fc8b3b9a1e18e3b_9.0.21022.8
     the files named: msvcm90.dll, msvcp90.dll and msvcr90.dll
   - from the directory starting with
     Windows/WinSxS/x86_Microsoft.VC90.MFC_1fc8b3b9a1e18e3b_9.0.21022.8
     the files named: mfc90.dll, mfc90u.dll, mfcm90.dll and mfcm90u.dll
   - from the directory named Windows/WinSxS/Manifests, the manifest file
     starting with x86_Microsoft.VC90.CRT_1fc8b3b9a1e18e3b_9.0.21022.8
     (rename it to Microsoft.VC90.CRT.manifest) and the manifest file starting
     with x86_Microsoft.VC90.MFC_1fc8b3b9a1e18e3b_9.0.21022.8 (rename it to
     Microsoft.VC90.MFC.manifest)
 
 Before building the installer, you have to build Mercurial HTML documentation 
 (or fix mercurial.iss to not reference the doc directory). Assuming you have an
 "asciidoc.bat" batch file somewhere in your PATH:
 
   cd doc
   mingw32-make ASCIIDOC=asciidoc.bat html
   cd ..
 
 If you use ISTool, you open the C:\hg\hg-release\contrib\win32\mercurial.iss
 file and type Ctrl-F9 to compile the installer file.
 
-Otherwise you run the Inno Setup compiler.  Assuming it's on the path you run:
+Otherwise you run the Inno Setup compiler.  Assuming it's in the path
+you should execute:
 
-  iscc contrib\win32\mercurial.iss
+  iscc contrib\win32\mercurial.iss /DVERSION=foo
 
-The actual installer will be in the C:\hg\hg-release\Output directory.
+Where 'foo' is the version number you would like to see in the
+'Add/Remove Applications' tool.  The installer will be placed into
+a directory named Output/ at the root of your repository.
 
 To automate the steps above you may want to create a batchfile based on the
 following:
 
   echo [build] > setup.cfg
   echo compiler=mingw32 >> setup.cfg
   python setup.py py2exe -b 1
   cd doc
   mingw32-make ASCIIDOC=asciidoc.bat html
   cd ..
-  iscc contrib\win32\mercurial.iss
+  iscc contrib\win32\mercurial.iss /DVERSION=snapshot
 
 and run it from the root of the hg repository (c:\hg\hg-release).